mirror of
https://github.com/vim/vim
synced 2025-07-16 01:01:58 +00:00
93197fde0f
Problem: The "*.*" browsefilter pattern only matches all files on Windows (Daryl Lee) Solution: Use "*" to filter on all platforms but keep "*.*" as the label text on Windows. (Fixes #12685, Doug Kearns) The *.* browsefilter pattern used to match "All Files" on Windows is a legacy of the DOS 8.3 filename wildcard matching algorithm. For reasons of backward compatibility this still works on Windows to match all files, even those without an extension. However, this pattern only matches filenames containing a dot on other platforms. This often makes files without an extension difficult to access from the file dialog, e.g., "Makefile" On Windows it is still standard practice to use "*.*" for the filter label so ftplugins should use "All Files (*.*)" on Windows and "All Files (*)" on other platforms. This matches Vim's default browsefilter values. This commit also normalises the browsefilter conditional test to check for the Win32 and GTK GUI features and an unset b:browsefilter. closes: #12759 Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
86 lines
2.4 KiB
VimL
86 lines
2.4 KiB
VimL
" Vim filetype plugin file
|
|
" Language: R Markdown file
|
|
" Maintainer: Jakson Alves de Aquino <jalvesaq@gmail.com>
|
|
" Homepage: https://github.com/jalvesaq/R-Vim-runtime
|
|
" Last Change: Mon May 29, 2023 06:31AM
|
|
" 2024 Jan 14 by Vim Project (browsefilter)
|
|
" Original work by Alex Zvoleff (adjusted from R help for rmd by Michel Kuhlmann)
|
|
|
|
" Only do this when not yet done for this buffer
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
|
|
if exists('g:rmd_include_html') && g:rmd_include_html
|
|
runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
|
|
endif
|
|
|
|
setlocal comments=fb:*,fb:-,fb:+,n:>
|
|
setlocal commentstring=#\ %s
|
|
setlocal formatoptions+=tcqln
|
|
setlocal formatlistpat=^\\s*\\d\\+\\.\\s\\+\\\|^\\s*[-*+]\\s\\+
|
|
setlocal iskeyword=@,48-57,_,.
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
function FormatRmd()
|
|
if search("^[ \t]*```[ ]*{r", "bncW") > search("^[ \t]*```$", "bncW")
|
|
setlocal comments=:#',:###,:##,:#
|
|
else
|
|
setlocal comments=fb:*,fb:-,fb:+,n:>
|
|
endif
|
|
return 1
|
|
endfunction
|
|
|
|
let s:last_line = 0
|
|
function SetRmdCommentStr()
|
|
if line('.') == s:last_line
|
|
return
|
|
endif
|
|
let s:last_line = line('.')
|
|
|
|
if (search("^[ \t]*```[ ]*{r", "bncW") > search("^[ \t]*```$", "bncW")) || ((search('^---$', 'Wn') || search('^\.\.\.$', 'Wn')) && search('^---$', 'bnW'))
|
|
set commentstring=#\ %s
|
|
else
|
|
set commentstring=<!--\ %s\ -->
|
|
endif
|
|
endfunction
|
|
|
|
" If you do not want both 'comments' and 'commentstring' dynamically defined,
|
|
" put in your vimrc: let g:rmd_dynamic_comments = 0
|
|
if !exists("g:rmd_dynamic_comments") || (exists("g:rmd_dynamic_comments") && g:rmd_dynamic_comments == 1)
|
|
setlocal formatexpr=FormatRmd()
|
|
augroup RmdCStr
|
|
autocmd!
|
|
autocmd CursorMoved <buffer> call SetRmdCommentStr()
|
|
augroup END
|
|
endif
|
|
|
|
" Enables pandoc if it is installed
|
|
unlet! b:did_ftplugin
|
|
runtime ftplugin/pandoc.vim
|
|
|
|
" Don't load another plugin for this buffer
|
|
let b:did_ftplugin = 1
|
|
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter = "R Source Files (*.R *.Rnw *.Rd *.Rmd *.Rrst *.qmd)\t*.R;*.Rnw;*.Rd;*.Rmd;*.Rrst;*.qmd\n"
|
|
if has("win32")
|
|
let b:browsefilter .= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter .= "All Files (*)\t*\n"
|
|
endif
|
|
endif
|
|
|
|
if exists('b:undo_ftplugin')
|
|
let b:undo_ftplugin .= " | setl cms< com< fo< flp< isk< | unlet! b:browsefilter"
|
|
else
|
|
let b:undo_ftplugin = "setl cms< com< fo< flp< isk< | unlet! b:browsefilter"
|
|
endif
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|
|
|
|
" vim: sw=2
|