mirror of
https://github.com/vim/vim
synced 2025-07-16 01:01:58 +00:00
93197fde0f
Problem: The "*.*" browsefilter pattern only matches all files on Windows (Daryl Lee) Solution: Use "*" to filter on all platforms but keep "*.*" as the label text on Windows. (Fixes #12685, Doug Kearns) The *.* browsefilter pattern used to match "All Files" on Windows is a legacy of the DOS 8.3 filename wildcard matching algorithm. For reasons of backward compatibility this still works on Windows to match all files, even those without an extension. However, this pattern only matches filenames containing a dot on other platforms. This often makes files without an extension difficult to access from the file dialog, e.g., "Makefile" On Windows it is still standard practice to use "*.*" for the filter label so ftplugins should use "All Files (*.*)" on Windows and "All Files (*)" on other platforms. This matches Vim's default browsefilter values. This commit also normalises the browsefilter conditional test to check for the Win32 and GTK GUI features and an unset b:browsefilter. closes: #12759 Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
77 lines
2.4 KiB
VimL
77 lines
2.4 KiB
VimL
" Vim filetype plugin file
|
|
" Language: C
|
|
" Maintainer: The Vim Project <https://github.com/vim/vim>
|
|
" Last Change: 2023 Aug 22
|
|
" Former Maintainer: Bram Moolenaar <Bram@vim.org>
|
|
|
|
" Only do this when not done yet for this buffer
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
|
|
" Don't load another plugin for this buffer
|
|
let b:did_ftplugin = 1
|
|
|
|
" Using line continuation here.
|
|
let s:cpo_save = &cpo
|
|
set cpo-=C
|
|
|
|
let b:undo_ftplugin = "setl fo< com< ofu< cms< def< inc< | if has('vms') | setl isk< | endif"
|
|
|
|
" Set 'formatoptions' to break comment lines but not other lines,
|
|
" and insert the comment leader when hitting <CR> or using "o".
|
|
setlocal fo-=t fo+=croql
|
|
|
|
" These options have the right value as default, but the user may have
|
|
" overruled that.
|
|
setlocal commentstring& define& include&
|
|
|
|
" Set completion with CTRL-X CTRL-O to autoloaded function.
|
|
if exists('&ofu')
|
|
setlocal ofu=ccomplete#Complete
|
|
endif
|
|
|
|
" Set 'comments' to format dashed lists in comments.
|
|
" Also include ///, used for Doxygen.
|
|
setlocal comments=sO:*\ -,mO:*\ \ ,exO:*/,s1:/*,mb:*,ex:*/,:///,://
|
|
|
|
" In VMS C keywords contain '$' characters.
|
|
if has("vms")
|
|
setlocal iskeyword+=$
|
|
endif
|
|
|
|
" When the matchit plugin is loaded, this makes the % command skip parens and
|
|
" braces in comments properly.
|
|
if !exists("b:match_words")
|
|
let b:match_words = '^\s*#\s*if\(\|def\|ndef\)\>:^\s*#\s*elif\>:^\s*#\s*else\>:^\s*#\s*endif\>'
|
|
let b:match_skip = 's:comment\|string\|character\|special'
|
|
let b:undo_ftplugin ..= " | unlet! b:match_skip b:match_words"
|
|
endif
|
|
|
|
" Win32 and GTK can filter files in the browse dialog
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
if &ft == "cpp"
|
|
let b:browsefilter = "C++ Source Files (*.cpp, *.c++)\t*.cpp;*.c++\n" ..
|
|
\ "C Header Files (*.h)\t*.h\n" ..
|
|
\ "C Source Files (*.c)\t*.c\n"
|
|
elseif &ft == "ch"
|
|
let b:browsefilter = "Ch Source Files (*.ch, *.chf)\t*.ch;*.chf\n" ..
|
|
\ "C Header Files (*.h)\t*.h\n" ..
|
|
\ "C Source Files (*.c)\t*.c\n"
|
|
else
|
|
let b:browsefilter = "C Source Files (*.c)\t*.c\n" ..
|
|
\ "C Header Files (*.h)\t*.h\n" ..
|
|
\ "Ch Source Files (*.ch, *.chf)\t*.ch;*.chf\n" ..
|
|
\ "C++ Source Files (*.cpp, *.c++)\t*.cpp;*.c++\n"
|
|
endif
|
|
if has("win32")
|
|
let b:browsefilter ..= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter ..= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin ..= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|