mirror of
https://github.com/vim/vim
synced 2025-07-15 16:51:57 +00:00
229f79c168
This commit fixes the following error message: ``` Compiler not supported: make inc< sw< sts< ``` 1. orginal value: `setl com< cms< et< fo<| compiler make inc< sw< sts<` 2. correct value: `setl com< cms< et< fo< inc< sw< sts< | compiler make` While at it, let's also document the g:yaml_recommended_style variable. closes: #17179 Co-authored-by: Christian Brabandt <cb@256bit.org> Signed-off-by: Vincent Law <vlaw@users.noreply.github.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
42 lines
1.1 KiB
VimL
42 lines
1.1 KiB
VimL
" Vim filetype plugin file
|
|
" Language: YAML (YAML Ain't Markup Language)
|
|
" Previous Maintainer: Nikolai Weibull <now@bitwi.se> (inactive)
|
|
" Last Change: 2024 Oct 04
|
|
" 2025 Apr 22 by Vim project re-order b:undo_ftplugin (#17179)
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
let b:undo_ftplugin = "setl com< cms< et< fo<"
|
|
|
|
setlocal comments=:# commentstring=#\ %s expandtab
|
|
setlocal formatoptions-=t formatoptions+=croql
|
|
|
|
if get(g:, "yaml_recommended_style",1)
|
|
let b:undo_ftplugin ..= " sw< sts<"
|
|
setlocal shiftwidth=2 softtabstop=2
|
|
endif
|
|
|
|
" rime input method engine(https://rime.im/)
|
|
" uses `*.custom.yaml` as its config files
|
|
if expand('%:r:e') ==# 'custom'
|
|
" `__include` command in `*.custom.yaml`
|
|
" see: https://github.com/rime/home/wiki/Configuration#%E5%8C%85%E5%90%AB
|
|
setlocal include=__include:\\s*
|
|
let b:undo_ftplugin ..= " inc<"
|
|
|
|
if !exists('current_compiler')
|
|
compiler rime_deployer
|
|
let b:undo_ftplugin ..= " | compiler make"
|
|
endif
|
|
endif
|
|
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|